{import * from CURL.GRAPHICS.SCENE}
{import * from CURL.PGUIDE.SCENEUTILS,
location = "../../default/support/SceneUtils.scurl"}
{define-class public BoundarySceneGraphic {inherits SceneGraphic}
field public circle:Circle
field public intersection-style:IntersectionStyle = IntersectionStyle.contained
{constructor public {default scene:Scene, circle:Circle, ...}
{construct-super scene, ... }
set self.circle = circle
}
{method public
{handle-motion
button-pressed:int,
dx:Distance,
dy:Distance}:void
{if button-pressed == 1 then
let (sx:double, sy:double, sz:double) =
{self.circle.transformation.to-world-scale}
let s:double = 20 / {max sx, sy, sz}
{self.circle.translate dx*s, -dy*s, 0m}
elseif button-pressed == 3 then
let s:float = (1 + dx/1in) asa float
{self.circle.scale s, s, s}
}
{for obj:SceneObject in self.scene.objects do
{if (obj isa Quad) then
set (obj asa Quad).fill-pattern = {FillPattern.get-silver}
}
}
{self.scene.handle-event
{BoundarySceneEvent
{self.circle.transformed-center},
{self.circle.transformed-radius},
self.intersection-style}
}
{self.update-drawable}
}
{method public {reset-quads}:void
{for obj:SceneObject in self.scene.objects do
{if (obj isa Quad) then
set (obj asa Quad).fill-pattern =
{FillPattern.get-silver}
}
}
{self.update-drawable}
}
}
{define-proc {make-command-button
label:String,
bsg:BoundarySceneGraphic,
intstyle:IntersectionStyle,
circle:Circle,
scene:Scene}:CommandButton
let button:CommandButton =
{CommandButton label=label,
width = 1in,
{on Action do
{bsg.reset-quads}
set bsg.intersection-style = intstyle
{scene.handle-event
{BoundarySceneEvent
{circle.transformed-center},
{circle.transformed-radius},
intstyle}
}
}
}
{return button}
}
{define-class public BoundarySceneEvent {inherits SphereIntersectionSceneEvent}
{constructor public
{default
center:Distance3d,
radius:Distance,
intersection-style:IntersectionStyle, ...}
{construct-super
center,
radius,
intersection-style = intersection-style,
predicate = Predicate.all,
sort-order = SortOrder.none,
...
}
}
}
{define-class public Circle {inherits SceneObject}
field public center:Distance3d = {Distance3d 0m, 0m, 0m}
field public radius:Distance
field public color:Color = {Palette.get-cyan}
{method public {paint renderer:Renderer3d,
viewport-width:Distance,
viewport-height:Distance}:void
let center:Distance3d = self.center
let radius:Distance = self.radius
{renderer.render-elliptic-path
center.x - radius, center.y - radius, 0m,
radius * 2, radius * 2,
texture=self.color, line-width = 1.5pt}
}
{method public
{get-local-bounding-box
check-visibility?:bool = false
}:(min-xyz:Distance3d, max-xyz:Distance3d, valid-bounds?:bool)
let center:Distance3d = self.center
let radius:Distance = self.radius
let a:Distance3d = {Distance3d center.x - radius, center.y - radius, 0m}
let b:Distance3d = {Distance3d center.x + radius, center.y + radius, 0m}
{return a, b, not check-visibility? or self.bounding-box-or-object-visible?}
}
{constructor public {default center:Distance3d, radius:Distance, ...}
{construct-super ... }
set self.center = center
set self.radius = radius
}
{method public {transformed-center}:Distance3d
{return {self.world-transformation.point-to-world self.center}}
}
{method public {transformed-radius}:Distance
let (sx:double, sy:double, sz:double) =
{self.world-transformation.to-world-scale}
{return self.radius * {max sx, sy, sz}}
}
}
{value
let scene:ExampleScene = {ExampleScene}
set scene.camera-position = {Distance3d 0in, -3ft, 5ft}
{scene.camera-setup}
let circle:Circle =
{Circle
{Distance3d 0m, 0m, 0m},
3.1ft
}
{scene.add-object circle}
let bsg:BoundarySceneGraphic =
{BoundarySceneGraphic
scene,
circle,
width=4in,
height=4in,
background = {FillPattern.get-black}
}
let eh:EventHandler =
{on e:BoundarySceneEvent at obj:Quad do
set obj.fill-pattern = {FillPattern.get-yellow}
{bsg.update-drawable}
}
let quad:#Quad
{for x:Distance = -5ft to 5ft step 1ft do
{for y:Distance = -5ft to 5ft step 1ft do
set quad =
{Quad
0ft, 0ft,
6in, 6in,
fill-pattern = {FillPattern.get-silver},
eh
}
{quad.translate x, y, 0m}
{scene.add-object {non-null quad}}
}
}
{VBox bsg,
{HBox
{make-command-button "always", bsg, IntersectionStyle.always, circle, scene},
{make-command-button "entirely-contained", bsg, IntersectionStyle.entirely-contained, circle, scene},
{make-command-button "contained", bsg, IntersectionStyle.contained, circle, scene},
{make-command-button "not-on-border", bsg, IntersectionStyle.not-on-border, circle, scene}
},
{HBox
{make-command-button "never", bsg, IntersectionStyle.never, circle, scene},
{make-command-button "outside", bsg, IntersectionStyle.outside, circle, scene},
{make-command-button "entirely-outside", bsg, IntersectionStyle.entirely-outside, circle, scene},
{make-command-button "only-on-border", bsg, IntersectionStyle.only-on-border, circle, scene}
}}} | |
